[SISTEMA] Duelos Ultimate

Ver el tema anterior Ver el tema siguiente Ir abajo

[SISTEMA] Duelos Ultimate

Mensaje por Koleshy el Vie Dic 18, 2015 2:32 pm

[SISTEMA] Duelos Ultimate



INFO: sistema avanzado de duelos, se puede configurar facilmente sin tener muchos conocimientos avanzados (eso creo xd)... puedes colocar las arenas que desees, equipos, restablecer la vida7mana que tenian antes de ir al duelo, su posicion, etc.

Código:
KE SDDU Config
   Acontecimientos
       Tiempo - Elapsed game time is 0.50 seconds
   Condiciones
   Acciones
       Set KE_SDDU_MSGs[1] = |c001CE6B9Duelo en:|r
       Set KE_SDDU_MSGs[2] = |c00FFFC01Iniciando Duelo!!!|r
       -------- Color de los numeros contador... --------
       Set KE_SDDU_MSGs[3] = |c00FF0303
       Set KE_SDDU_MSGs[4] = |c00FF0303GO!!!|r
       Set KE_SDDU_MSGs[5] = |c0080FF00Auto-Finalizar en:|r
       Set KE_SDDU_MSGs[6] = Empate!!!
       Set KE_SDDU_MSGs[7] = El tiempo de duelo Expiro!!!
       -------- - --------
       -------- Cada cuanto tiempo empieza un duelo (segundos) --------
       Set KE_SDDU_Tiempo[0] = 30.00
       -------- En cuanto tiempo Auto-Finaliza el duelo (segundos) --------
       Set KE_SDDU_Tiempo[1] = 45.00
       -------- - --------
       -------- Zona del mapa completo, o ya sea solo una region depende de ustedes --------
       Set KE_SDDU_Zona[0] = (Playable map area)
       For each (Integer A) from 1 to 12, do (Actions)
           Bucle: Acciones
               Cámara - Set the camera bounds for (Player((Integer A))) to KE_SDDU_Zona[0]
       -------- - --------
       -------- True = regresa a los heroes a la posicion donde estaban, tambien la vida y mana que tenian antes de ir al duelo. --------
       -------- False = los mueve a la region de respawn establecida por equipo. (por defecto restablece vida/mana 100%) --------
       Set KE_SDDU_MoveBool = True
       -------- - --------
       -------- IMPORTANTE: Sobre la variable 'KE_SDDU_Team' --------
       -------- en su formacion se coloca la cantidad de equipos que usaras --------
       -------- en este caso yo coloque 2, porque estoy usando solo 2, si usan mas aumentenle --------
       -------- - --------
       -------- <<< Equipo 1 >>> --------
       Grupo de jugadores - Add Jugador 1 (rojo) to KE_SDDU_Team[1]
       Grupo de jugadores - Add Jugador 2 (azul) to KE_SDDU_Team[1]
       Grupo de jugadores - Add Jugador 3 (teja) to KE_SDDU_Team[1]
       Grupo de jugadores - Add Jugador 4 (morado) to KE_SDDU_Team[1]
       Grupo de jugadores - Add Jugador 5 (amarillo) to KE_SDDU_Team[1]
       -------- Region donde reviviran los del Equipo 1 (Al finalizar un duelo) --------
       Set KE_SDDU_Respawn[1] = RespawnTeam1 <gen>
       -------- <<< Equipo 2 >>> --------
       Grupo de jugadores - Add Jugador 6 (naranja) to KE_SDDU_Team[2]
       Grupo de jugadores - Add Jugador 7 (verde) to KE_SDDU_Team[2]
       Grupo de jugadores - Add Jugador 8 (rosa) to KE_SDDU_Team[2]
       Grupo de jugadores - Add Jugador 9 (Gris) to KE_SDDU_Team[2]
       Grupo de jugadores - Add Jugador 10 (azul claro) to KE_SDDU_Team[2]
       -------- Region donde reviviran los del Equipo 2 (Al finalizar un duelo) --------
       Set KE_SDDU_Respawn[2] = RespawnTeam2 <gen>
       -------- - --------
       -------- Cantidad Total de Equipos --------
       Set KE_SDDU_TeamsTotal = 2
       -------- - --------
       -------- Zona(s) de Duelo --------
       Set KE_SDDU_Zona[1] = Zona1 <gen>
       Set KE_SDDU_Zona[2] = Zona2 <gen>
       -------- - --------
       -------- Cantidad Total de Zonas --------
       Set KE_SDDU_ZonasTotal = 2

Detonadores de Ejecucion:

Código:
KE SDDU RelojEmpezar
   Acontecimientos
   Condiciones
   Acciones
       -------- Con este Detonador se Inicia el Sistema --------
       -------- - --------
       Cuenta atrás del reloj - Start KE_SDDU_Reloj[0] as a Un tiro timer that will expire in KE_SDDU_Tiempo[0] seconds
       Cuenta atrás del reloj - Create a timer window for KE_SDDU_Reloj[0] with title KE_SDDU_MSGs[1]
       Set KE_SDDU_Reloj_Ventana[0] = (Last created timer window)
       -------- - --------
       -------- Usa la Accion de abajo cuando quieras iniciar el Sistema (pero no aqui) --------
       -------- Ejemplo: en un detonador blanco, con evento de 'Elapsed game time is 1.00 seconds' --------
       Detonador - Run KE SDDU RelojEmpezar <gen> (ignoring conditions)

Código:
KE SDDU GuardarHeroe
   Acontecimientos
       Unidad - A unit enters (Playable map area)
   Condiciones
       ((Triggering unit) is Un hé️roe) Igual a True
       KE_SDDU_Bool[(Player number of (Owner of (Entering unit)))] Igual a False
   Acciones
       Set KE_SDDU_Bool[(Player number of (Owner of (Entering unit)))] = True
       Set KE_SDDU_Heroe[(Player number of (Owner of (Entering unit)))] = (Entering unit)

Código:
KE SDDU GuardarPosHpMp
   Acontecimientos
   Condiciones
   Acciones
       If (All Conditions are True) then do (Then Actions) else do (Else Actions)
           Si: Condiciones
               KE_SDDU_MoveBool Igual a True
           Entonces: Acciones
               For each (Integer A) from 1 to 12, do (Actions)
                   Bucle: Acciones
                       If (All Conditions are True) then do (Then Actions) else do (Else Actions)
                           Si: Condiciones
                               ((Player((Integer A))) slot status) Igual a Está jugando
                           Entonces: Acciones
                               If (All Conditions are True) then do (Then Actions) else do (Else Actions)
                                   Si: Condiciones
                                       (KE_SDDU_Heroe[(Integer A)] is alive) Igual a True
                                   Entonces: Acciones
                                       Set KE_SDDU_HeroPos[(Integer A)] = (Position of KE_SDDU_Heroe[(Integer A)])
                                       -------- - --------
                                       Set KE_SDDU_HP[(Integer A)] = (Vida of KE_SDDU_Heroe[(Integer A)])
                                       Set KE_SDDU_MP[(Integer A)] = (Maná of KE_SDDU_Heroe[(Integer A)])
                                   Otros: Acciones
                                       Set KE_SDDU_HP[(Integer A)] = (Vida máx. of KE_SDDU_Heroe[(Integer A)])
                                       Set KE_SDDU_MP[(Integer A)] = (Maná máx. of KE_SDDU_Heroe[(Integer A)])
                                       -------- - --------
                                       For each (Integer B) from 1 to KE_SDDU_TeamsTotal, do (Actions)
                                           Bucle: Acciones
                                               If (All Conditions are True) then do (Then Actions) else do (Else Actions)
                                                   Si: Condiciones
                                                       ((Player((Integer A))) is in KE_SDDU_Team[(Integer B)]) Igual a True
                                                   Entonces: Acciones
                                                       Set KE_SDDU_HeroPos[(Integer A)] = (Random point in KE_SDDU_Respawn[(Integer B)])
                                                   Otros: Acciones
                           Otros: Acciones
           Otros: Acciones
               For each (Integer A) from 1 to 12, do (Actions)
                   Bucle: Acciones
                       If (All Conditions are True) then do (Then Actions) else do (Else Actions)
                           Si: Condiciones
                               ((Player((Integer A))) slot status) Igual a Está jugando
                           Entonces: Acciones
                               For each (Integer B) from 1 to KE_SDDU_TeamsTotal, do (Actions)
                                   Bucle: Acciones
                                       If (All Conditions are True) then do (Then Actions) else do (Else Actions)
                                           Si: Condiciones
                                               ((Player((Integer A))) is in KE_SDDU_Team[(Integer B)]) Igual a True
                                           Entonces: Acciones
                                               Set KE_SDDU_HeroPos[(Integer A)] = (Random point in KE_SDDU_Respawn[(Integer B)])
                                           Otros: Acciones
                               -------- - --------
                               Set KE_SDDU_HP[(Integer A)] = (Vida máx. of KE_SDDU_Heroe[(Integer A)])
                               Set KE_SDDU_MP[(Integer A)] = (Maná máx. of KE_SDDU_Heroe[(Integer A)])
                           Otros: Acciones

Código:
KE SDDU Iniciado
   Acontecimientos
       Tiempo - KE_SDDU_Reloj[0] expires
   Condiciones
   Acciones
       -------- << CONFIGURAR >>> --------
       -------- IMPORTANTE: Si tienes un deto/sistema de respawn --------
       -------- en esta parte debes desactivarlo (Off) --------
       -------- - --------
       -------- Ejemplo: cuando empiece el duelo, no apareceran creeps. --------
       Detonador - Turn off CreandoCreeps <gen>
       -------- - --------
       Cuenta atrás del reloj - Destroy KE_SDDU_Reloj_Ventana[0]
       -------- - --------
       Partida - Display to (All players) the text: KE_SDDU_MSGs[2]
       Detonador - Turn on KE SDDU Volver <gen>
       Detonador - Run KE SDDU GuardarPosHpMp <gen> (ignoring conditions)
       Unidad - Activar pausa all units
       -------- - --------
       Wait 2.00 seconds
       -------- - --------
       Set KE_SDDU_RndINT = (Random integer number between 1 and KE_SDDU_ZonasTotal)
       Set KE_SDDU_RM_Region = KE_SDDU_Zona[KE_SDDU_RndINT]
       Detonador - Run KE SDDU RevivirMover <gen> (ignoring conditions)
       -------- - --------
       For each (Integer A) from 1 to 12, do (Actions)
           Bucle: Acciones
               Unidad - Make KE_SDDU_Heroe[(Integer A)] Invulnerable
       -------- - --------
       Set KE_SDDU_Contador = 6
       Detonador - Turn on KE SDDU Contador <gen>

Código:
KE SDDU RevivirMover
   Acontecimientos
   Condiciones
   Acciones
       Set KE_SDDU_RM_Region = KE_SDDU_RM_Region
       Unidad - Activar pausa all units
       -------- - --------
       For each (Integer A) from 1 to 12, do (Actions)
           Bucle: Acciones
               If (All Conditions are True) then do (Then Actions) else do (Else Actions)
                   Si: Condiciones
                       ((Player((Integer A))) slot status) Igual a Está jugando
                   Entonces: Acciones
                       Cámara - Set the camera bounds for (Player((Integer A))) to KE_SDDU_RM_Region
                       If (All Conditions are True) then do (Then Actions) else do (Else Actions)
                           Si: Condiciones
                               KE_SDDU_Finalizar Igual a False
                           Entonces: Acciones
                               Set KE_SDDU_P = (Random point in KE_SDDU_RM_Region)
                               Set KE_SDDU_HpX = (Vida máx. of KE_SDDU_Heroe[(Integer A)])
                               Set KE_SDDU_MpX = (Maná máx. of KE_SDDU_Heroe[(Integer A)])
                           Otros: Acciones
                               Set KE_SDDU_P = KE_SDDU_HeroPos[(Integer A)]
                               Set KE_SDDU_HpX = KE_SDDU_HP[(Integer A)]
                               Set KE_SDDU_MpX = KE_SDDU_MP[(Integer A)]
                       -------- - --------
                       Hé️roe - Instantly revive KE_SDDU_Heroe[(Integer A)] at KE_SDDU_P, Ocultar revival graphics
                       Unidad - Move KE_SDDU_Heroe[(Integer A)] instantly to KE_SDDU_P
                       Cámara - Pan camera for (Player((Integer A))) to KE_SDDU_P over 0.00 seconds
                       Custom script:   call RemoveLocation(udg_KE_SDDU_P)
                       Unidad - Set life of KE_SDDU_Heroe[(Integer A)] to KE_SDDU_HpX
                       Unidad - Set mana of KE_SDDU_Heroe[(Integer A)] to KE_SDDU_MpX
                       Unidad - Desactivar pausa KE_SDDU_Heroe[(Integer A)]
                       Selección - Clear selection for (Player((Integer A)))
                       Selección - Select KE_SDDU_Heroe[(Integer A)] for (Player((Integer A)))
                   Otros: Acciones

Código:
KE SDDU Contador
   Acontecimientos
       Tiempo - Every 1.00 seconds of game time
   Condiciones
   Acciones
       If (All Conditions are True) then do (Then Actions) else do (Else Actions)
           Si: Condiciones
               KE_SDDU_Contador Igual a 1
           Entonces: Acciones
               Partida - Display to (All players) the text: KE_SDDU_MSGs[4]
               Detonador - Run KE SDDU HeroesActuales <gen> (ignoring conditions)
               -------- - --------
               Cuenta atrás del reloj - Start KE_SDDU_Reloj[1] as a Un tiro timer that will expire in KE_SDDU_Tiempo[1] seconds
               Cuenta atrás del reloj - Create a timer window for KE_SDDU_Reloj[1] with title KE_SDDU_MSGs[5]
               Set KE_SDDU_Reloj_Ventana[1] = (Last created timer window)
               -------- - --------
               Detonador - Turn on KE SDDU Matadas <gen>
               Detonador - Turn on KE SDDU Kiter <gen>
               For each (Integer A) from 1 to 12, do (Actions)
                   Bucle: Acciones
                       If (All Conditions are True) then do (Then Actions) else do (Else Actions)
                           Si: Condiciones
                               ((Player((Integer A))) slot status) Igual a Está jugando
                           Entonces: Acciones
                               Unidad - Make KE_SDDU_Heroe[(Integer A)] Vulnerable
                           Otros: Acciones
               -------- - --------
               Detonador - Turn off (This trigger)
           Otros: Acciones
               Set KE_SDDU_Contador = (KE_SDDU_Contador - 1)
               Partida - Display to (All players) the text: (KE_SDDU_MSGs[3] + ((String(KE_SDDU_Contador)) + |r))

Código:
KE SDDU HeroesActuales
   Acontecimientos
   Condiciones
   Acciones
       For each (Integer A) from 1 to KE_SDDU_TeamsTotal, do (Actions)
           Bucle: Acciones
               Set KE_SDDU_HA_N[(Integer A)] = 0
       -------- - --------
       For each (Integer A) from 1 to KE_SDDU_TeamsTotal, do (Actions)
           Bucle: Acciones
               Grupo de jugadores - Pick every player in KE_SDDU_Team[(Integer A)] and do (Actions)
                   Bucle: Acciones
                       If (All Conditions are True) then do (Then Actions) else do (Else Actions)
                           Si: Condiciones
                               ((Picked player) slot status) Igual a Está jugando
                               (KE_SDDU_Heroe[(Player number of (Picked player))] is alive) Igual a True
                           Entonces: Acciones
                               Set KE_SDDU_HA_N[(Integer A)] = (KE_SDDU_HA_N[(Integer A)] + 1)
                           Otros: Acciones

Código:
KE SDDU Matadas
   Acontecimientos
       Unidad - A unit Muere
   Condiciones
       ((Triggering unit) is Un hé️roe) Igual a True
   Acciones
       For each (Integer A) from 1 to KE_SDDU_TeamsTotal, do (Actions)
           Bucle: Acciones
               If (All Conditions are True) then do (Then Actions) else do (Else Actions)
                   Si: Condiciones
                       ((Owner of (Triggering unit)) is in KE_SDDU_Team[(Integer A)]) Igual a True
                   Entonces: Acciones
                       Set KE_SDDU_HA_N[(Integer A)] = (KE_SDDU_HA_N[(Integer A)] - 1)
                   Otros: Acciones
       -------- - --------
       Detonador - Run KE SDDU Ganador <gen> (ignoring conditions)

Código:
KE SDDU Kiter
   Acontecimientos
       Jugador - Jugador 1 (rojo) leaves the game
       Jugador - Jugador 2 (azul) leaves the game
       Jugador - Jugador 3 (teja) leaves the game
       Jugador - Jugador 4 (morado) leaves the game
       Jugador - Jugador 5 (amarillo) leaves the game
       Jugador - Jugador 6 (naranja) leaves the game
       Jugador - Jugador 7 (verde) leaves the game
       Jugador - Jugador 8 (rosa) leaves the game
       Jugador - Jugador 9 (Gris) leaves the game
       Jugador - Jugador 10 (azul claro) leaves the game
       Jugador - Jugador 11 (verde oscuro) leaves the game
       Jugador - Jugador 12 (marrón) leaves the game
   Condiciones
       KE_SDDU_Bool[(Player number of (Triggering player))] Igual a True
   Acciones
       If (All Conditions are True) then do (Then Actions) else do (Else Actions)
           Si: Condiciones
               (KE_SDDU_Heroe[(Player number of (Triggering player))] is alive) Igual a True
           Entonces: Acciones
               For each (Integer A) from 1 to KE_SDDU_TeamsTotal, do (Actions)
                   Bucle: Acciones
                       If (All Conditions are True) then do (Then Actions) else do (Else Actions)
                           Si: Condiciones
                               ((Triggering player) is in KE_SDDU_Team[(Integer A)]) Igual a True
                           Entonces: Acciones
                               Set KE_SDDU_HA_N[(Integer A)] = (KE_SDDU_HA_N[(Integer A)] - 1)
                           Otros: Acciones
           Otros: Acciones
       -------- - --------
       Detonador - Run KE SDDU Ganador <gen> (ignoring conditions)
       Unidad - Remove KE_SDDU_Heroe[(Player number of (Triggering player))] from the game
       Set KE_SDDU_Heroe[(Player number of (Triggering player))] = Ninguna unidad

Código:
KE SDDU Ganador
   Acontecimientos
   Condiciones
   Acciones
       If (All Conditions are True) then do (Then Actions) else do (Else Actions)
           Si: Condiciones
               KE_SDDU_Finalizar Igual a False
           Entonces: Acciones
               Set KE_SDDU_M[1] = 0
               Set KE_SDDU_M[2] = 0
               Set KE_SDDU_M[3] = 0
               -------- - --------
               For each (Integer A) from 1 to KE_SDDU_TeamsTotal, do (Actions)
                   Bucle: Acciones
                       If (All Conditions are True) then do (Then Actions) else do (Else Actions)
                           Si: Condiciones
                               KE_SDDU_HA_N[(Integer A)] Igual a 0
                           Entonces: Acciones
                               Set KE_SDDU_M[1] = (KE_SDDU_M[1] + 1)
                           Otros: Acciones
                       If (All Conditions are True) then do (Then Actions) else do (Else Actions)
                           Si: Condiciones
                               KE_SDDU_HA_N[(Integer A)] Mayor que 0
                           Entonces: Acciones
                               Set KE_SDDU_M[2] = (KE_SDDU_M[2] + 1)
                               Set KE_SDDU_M[3] = (Integer A)
                           Otros: Acciones
               -------- - --------
               If (All Conditions are True) then do (Then Actions) else do (Else Actions)
                   Si: Condiciones
                       KE_SDDU_M[1] Mayor que 0
                       KE_SDDU_M[2] Igual a 1
                   Entonces: Acciones
                       Set KE_SDDU_Finalizar = True
                       Set KE_SDDU_MSG = (Gano el Equipo  + (String(KE_SDDU_M[3])))
                   Otros: Acciones
                       If (All Conditions are True) then do (Then Actions) else do (Else Actions)
                           Si: Condiciones
                               KE_SDDU_M[1] Mayor que 0
                               KE_SDDU_M[2] Igual a 0
                           Entonces: Acciones
                               Set KE_SDDU_Finalizar = True
                               Set KE_SDDU_MSG = KE_SDDU_MSGs[6]
                           Otros: Acciones
           Otros: Acciones
       If (All Conditions are True) then do (Then Actions) else do (Else Actions)
           Si: Condiciones
               KE_SDDU_Finalizar Igual a True
           Entonces: Acciones
               Detonador - Run KE SDDU Regresar <gen> (ignoring conditions)
           Otros: Acciones

Código:
KE SDDU Regresar
   Acontecimientos
   Condiciones
   Acciones
       -------- << CONFIGURAR >>> --------
       -------- IMPORTANTE: Sobre el deto/sistema de respawn que desabilitaste --------
       -------- en esta parte debes activarlo (On) --------
       -------- - --------
       -------- Ejemplo: ya termino el duelo, asi que activamos nuevamente el spawn de creeps --------
       Detonador - Turn on CreandoCreeps <gen>
       -------- - --------
       Cuenta atrás del reloj - Destroy KE_SDDU_Reloj_Ventana[1]
       Detonador - Turn off KE SDDU Matadas <gen>
       Detonador - Turn off KE SDDU Kiter <gen>
       Detonador - Turn off KE SDDU Volver <gen>
       -------- - --------
       Unidad - Activar pausa all units
       Partida - Display to (All players) the text: KE_SDDU_MSG
       Wait 2.00 seconds
       -------- - --------
       Set KE_SDDU_RM_Region = KE_SDDU_Zona[0]
       Detonador - Run KE SDDU RevivirMover <gen> (ignoring conditions)
       Unidad - Desactivar pausa all units
       -------- - --------
       Wait 2.00 seconds
       -------- - --------
       For each (Integer A) from 1 to 12, do (Actions)
           Bucle: Acciones
               Custom script:   call RemoveLocation(udg_KE_SDDU_HeroPos[bj_forLoopAIndex])
       -------- - --------
       Set KE_SDDU_Finalizar = False
       Detonador - Run KE SDDU RelojEmpezar <gen> (ignoring conditions)

Código:
KE SDDU Volver
   Acontecimientos
       Tiempo - KE_SDDU_Reloj[1] expires
   Condiciones
   Acciones
       Set KE_SDDU_Finalizar = True
       -------- - --------
       Set KE_SDDU_MSG = KE_SDDU_MSGs[7]
       Detonador - Run KE SDDU Regresar <gen> (ignoring conditions)

EXTRAS:

-  Spawn de creeps cada X segundos
-  Spawn random de heroes.

descarga
[Tienes que estar registrado y conectado para ver este vínculo]
avatar
Koleshy
Pendejo
Pendejo

Mensajes : 37
Fecha de inscripción : 21/11/2013
Edad : 21
Localización : Lima, Perú

Ver perfil de usuario http://koleshyengine.foroactivo.mx

Volver arriba Ir abajo

Ver el tema anterior Ver el tema siguiente Volver arriba


 
Permisos de este foro:
No puedes responder a temas en este foro.